home *** CD-ROM | disk | FTP | other *** search
/ Aminet 5 / Aminet 5 - March 1995.iso / Aminet / util / gnu / a2_0b_Emacs_sr.lha / Emacs-19.25 / lisp / server.el < prev    next >
Lisp/Scheme  |  1994-05-28  |  14KB  |  363 lines
  1. ;;; server.el --- Lisp code for GNU Emacs running as server process.
  2.  
  3. ;; Copyright (C) 1986, 1987, 1992, 1994 Free Software Foundation, Inc.
  4.  
  5. ;; Author: William Sommerfeld <wesommer@athena.mit.edu>
  6. ;; Keywords: processes
  7.  
  8. ;; Changes by peck@sun.com and by rms.
  9.  
  10. ;; This file is part of GNU Emacs.
  11.  
  12. ;; GNU Emacs is free software; you can redistribute it and/or modify
  13. ;; it under the terms of the GNU General Public License as published by
  14. ;; the Free Software Foundation; either version 2, or (at your option)
  15. ;; any later version.
  16.  
  17. ;; GNU Emacs is distributed in the hope that it will be useful,
  18. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20. ;; GNU General Public License for more details.
  21.  
  22. ;; You should have received a copy of the GNU General Public License
  23. ;; along with GNU Emacs; see the file COPYING.  If not, write to
  24. ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  25.  
  26. ;;; Commentary:
  27.  
  28. ;;; This Lisp code is run in Emacs when it is to operate as
  29. ;;; a server for other processes.
  30.  
  31. ;;; Load this library and do M-x server-edit to enable Emacs as a server.
  32. ;;; Emacs runs the program ../arch-lib/emacsserver as a subprocess
  33. ;;; for communication with clients.  If there are no client buffers to edit, 
  34. ;;; server-edit acts like (switch-to-buffer (other-buffer))
  35.  
  36. ;;; When some other program runs "the editor" to edit a file,
  37. ;;; "the editor" can be the Emacs client program ../lib-src/emacsclient.
  38. ;;; This program transmits the file names to Emacs through
  39. ;;; the server subprocess, and Emacs visits them and lets you edit them.
  40.  
  41. ;;; Note that any number of clients may dispatch files to emacs to be edited.
  42.  
  43. ;;; When you finish editing a Server buffer, again call server-edit
  44. ;;; to mark that buffer as done for the client and switch to the next 
  45. ;;; Server buffer.  When all the buffers for a client have been edited 
  46. ;;; and exited with server-edit, the client "editor" will return
  47. ;;; to the program that invoked it.  
  48.  
  49. ;;; Your editing commands and Emacs's display output go to and from
  50. ;;; the terminal in the usual way.  Thus, server operation is possible
  51. ;;; only when Emacs can talk to the terminal at the time you invoke
  52. ;;; the client.  This is possible in four cases:
  53.  
  54. ;;; 1. On a window system, where Emacs runs in one window and the
  55. ;;; program that wants to use "the editor" runs in another.
  56.  
  57. ;;; 2. On a multi-terminal system, where Emacs runs on one terminal and the
  58. ;;; program that wants to use "the editor" runs on another.
  59.  
  60. ;;; 3. When the program that wants to use "the editor" is running
  61. ;;; as a subprocess of Emacs.
  62.  
  63. ;;; 4. On a system with job control, when Emacs is suspended, the program
  64. ;;; that wants to use "the editor" will stop and display
  65. ;;; "Waiting for Emacs...".  It can then be suspended, and Emacs can be
  66. ;;; brought into the foreground for editing.  When done editing, Emacs is
  67. ;;; suspended again, and the client program is brought into the foreground.
  68.  
  69. ;;; The buffer local variable "server-buffer-clients" lists 
  70. ;;; the clients who are waiting for this buffer to be edited.  
  71. ;;; The global variable "server-clients" lists all the waiting clients,
  72. ;;; and which files are yet to be edited for each.
  73.  
  74. ;;; Code:
  75.  
  76. (defvar server-program (expand-file-name "emacsserver" exec-directory)
  77.   "*The program to use as the edit server.")
  78.  
  79. (defvar server-visit-hook nil
  80.   "*List of hooks to call when visiting a file for the Emacs server.")
  81.  
  82. (defvar server-switch-hook nil
  83.   "*List of hooks to call when switching to a buffer for the Emacs server.")
  84.  
  85. (defvar server-done-hook nil
  86.   "*List of hooks to call when done editing a buffer for the Emacs server.")
  87.  
  88. (defvar server-process nil 
  89.   "the current server process")
  90.  
  91. (defvar server-previous-string "")
  92.  
  93. (defvar server-clients nil
  94.   "List of current server clients.
  95. Each element is (CLIENTID BUFFERS...) where CLIENTID is a string
  96. that can be given to the server process to identify a client.
  97. When a buffer is marked as \"done\", it is removed from this list.")
  98.  
  99. (defvar server-buffer-clients nil
  100.   "List of clientids for clients requesting editing of current buffer.")
  101. (make-variable-buffer-local 'server-buffer-clients)
  102. ;; Changing major modes should not erase this local.
  103. (put 'server-buffer-clients 'permanent-local t)
  104.  
  105. (defvar server-window nil
  106.   "*The window to use for selecting Emacs server buffers.
  107. If nil, use the selected window.
  108. If it is a frame, use the frame's selected window.")
  109.  
  110. (defvar server-temp-file-regexp "^/tmp/Re\\|/draft$"
  111.   "*Regexp which should match filenames of temporary files
  112. which are deleted and reused after each edit
  113. by the programs that invoke the emacs server.")
  114.  
  115. (or (assq 'server-buffer-clients minor-mode-alist)
  116.     (setq minor-mode-alist (cons '(server-buffer-clients " Server") minor-mode-alist)))
  117.  
  118. ;; If a *server* buffer exists,
  119. ;; write STRING to it for logging purposes.
  120. (defun server-log (string)
  121.   (if (get-buffer "*server*")
  122.       (save-excursion
  123.     (set-buffer "*server*")
  124.     (goto-char (point-max))
  125.     (insert string)
  126.     (or (bobp) (newline)))))
  127.  
  128. (defun server-sentinel (proc msg)
  129.   (cond ((eq (process-status proc) 'exit)
  130.      (server-log (message "Server subprocess exited")))
  131.     ((eq (process-status proc) 'signal)
  132.      (server-log (message "Server subprocess killed")))))
  133.  
  134. ;;;###autoload
  135. (defun server-start (&optional leave-dead)
  136.   "Allow this Emacs process to be a server for client processes.
  137. This starts a server communications subprocess through which
  138. client \"editors\" can send your editing commands to this Emacs job.
  139. To use the server, set up the program `etc/emacsclient' in the
  140. Emacs distribution as your standard \"editor\".
  141.  
  142. Prefix arg means just kill any existing server communications subprocess."
  143.   (interactive "P")
  144.   ;; kill it dead!
  145.   (if server-process
  146.       (progn
  147.     (set-process-sentinel server-process nil)
  148.     (condition-case () (delete-process server-process) (error nil))))
  149.   (condition-case () (delete-file "~/.emacs_server") (error nil))
  150.   ;; If we already had a server, clear out associated status.
  151.   (while server-clients
  152.     (let ((buffer (nth 1 (car server-clients))))
  153.       (server-buffer-done buffer)))
  154.   (if leave-dead
  155.       nil
  156.     (if server-process
  157.     (server-log (message "Restarting server")))
  158.     (setq server-process (start-process "server" nil server-program))
  159.     (set-process-sentinel server-process 'server-sentinel)
  160.     (set-process-filter server-process 'server-process-filter)
  161.     (process-kill-without-query server-process)))
  162.  
  163. ;Process a request from the server to edit some files.
  164. ;Format of STRING is "Client: CLIENTID PATH PATH PATH... \n"
  165. (defun server-process-filter (proc string)
  166.   (server-log string)
  167.   (setq string (concat server-previous-string string))
  168.   (if (not (and (eq ?\n (aref string (1- (length string))))
  169.         (eq 0 (string-match "Client: " string))))
  170.       ;; If input is not complete, save it for later.
  171.       (setq server-previous-string string)
  172.     ;; If it is complete, process it now, and discard what was saved.
  173.     (setq string (substring string (match-end 0)))
  174.     (setq server-previous-string "")
  175.     (let ((client (list (substring string 0 (string-match " " string))))
  176.       (files nil)
  177.       (lineno 1))
  178.       (setq string (substring string (match-end 0)))
  179.       (while (string-match "[^ ]+ " string)
  180.     (let ((arg
  181.            (substring string (match-beginning 0) (1- (match-end 0)))))
  182.       (setq string (substring string (match-end 0)))
  183.       (if (string-match "\\`\\+[0-9]+\\'" arg)
  184.           (setq lineno (read (substring arg 1)))
  185.         (setq files
  186.           (cons (list arg lineno)
  187.             files))
  188.         (setq lineno 1))))
  189.       (server-visit-files files client)
  190.       ;; CLIENT is now a list (CLIENTNUM BUFFERS...)
  191.       (setq server-clients (cons client server-clients))
  192.       (server-switch-buffer (nth 1 client))
  193.       (run-hooks 'server-switch-hook)
  194.       (message (substitute-command-keys
  195.         "When done with a buffer, type \\[server-edit].")))))
  196.  
  197. (defun server-visit-files (files client)
  198.   "Finds FILES and returns the list CLIENT with the buffers nconc'd.
  199. FILES is an alist whose elements are (FILENAME LINENUMBER)."
  200.   ;; Bind last-nonmenu-event to force use of keyboard, not mouse, for queries.
  201.   (let (client-record (last-nonmenu-event t) (obuf (current-buffer)))
  202.     ;; Restore the current buffer afterward, but not using save-excursion,
  203.     ;; because we don't want to save point in this buffer
  204.     ;; if it happens to be one of those specified by the server.
  205.     (unwind-protect
  206.     (while files
  207.       ;; If there is an existing buffer modified or the file is modified,
  208.       ;; revert it.
  209.       ;; If there is an existing buffer with deleted file, offer to write it.
  210.       (let* ((filen (car (car files)))
  211.          (obuf (get-file-buffer filen)))
  212.         (if (and obuf (set-buffer obuf))
  213.         (if (file-exists-p filen)
  214.             (if (or (not (verify-visited-file-modtime obuf))
  215.                 (buffer-modified-p obuf))
  216.             (revert-buffer t nil))
  217.           (if (y-or-n-p
  218.                (concat "File no longer exists: "
  219.                    filen
  220.                    ", write buffer to file? "))
  221.               (write-file filen)))
  222.           (set-buffer (find-file-noselect filen))
  223.           (run-hooks 'server-visit-hook)))
  224.       (goto-line (nth 1 (car files)))
  225.       (setq server-buffer-clients (cons (car client) server-buffer-clients))
  226.       (setq client-record (cons (current-buffer) client-record))
  227.       (setq files (cdr files)))
  228.       (set-buffer obuf))
  229.     (nconc client client-record)))
  230.  
  231. (defun server-buffer-done (buffer)
  232.   "Mark BUFFER as \"done\" for its client(s).
  233. Buries the buffer, and returns another server buffer
  234. as a suggestion for what to select next."
  235.   (let ((running (eq (process-status server-process) 'run))
  236.     (next-buffer nil)
  237.     (old-clients server-clients))
  238.     (while old-clients
  239.       (let ((client (car old-clients)))
  240.     (or next-buffer 
  241.         (setq next-buffer (nth 1 (memq buffer client))))
  242.     (delq buffer client)
  243.     ;; If client now has no pending buffers,
  244.     ;; tell it that it is done, and forget it entirely.
  245.     (if (cdr client) nil
  246.       (if running
  247.           (progn
  248.         (send-string server-process 
  249.                  (format "Close: %s Done\n" (car client)))
  250.         (server-log (format "Close: %s Done\n" (car client)))))
  251.       (setq server-clients (delq client server-clients))))
  252.       (setq old-clients (cdr old-clients)))
  253.     (if (buffer-name buffer)
  254.     (progn
  255.       (save-excursion
  256.         (set-buffer buffer)
  257.         (setq server-buffer-clients nil)
  258.         (run-hooks 'server-done-hook))
  259.       (if (server-temp-file-p buffer)
  260.           (kill-buffer buffer)
  261.         (bury-buffer buffer))))
  262.     next-buffer))
  263.  
  264. (defun server-temp-file-p (buffer)
  265.   "Return non-nil if BUFFER contains a file considered temporary.
  266. These are files whose names suggest they are repeatedly
  267. reused to pass information to another program.
  268.  
  269. The variable `server-temp-file-regexp' controls which filenames
  270. are considered temporary."
  271.   (and (buffer-file-name buffer)
  272.        (string-match server-temp-file-regexp (buffer-file-name buffer))))
  273.  
  274. (defun server-done ()
  275.   "Offer to save current buffer, mark it as \"done\" for clients.
  276. Then bury it, and return a suggested buffer to select next."
  277.   (let ((buffer (current-buffer)))
  278.     (if server-buffer-clients
  279.     (progn
  280.        (if (server-temp-file-p buffer)
  281.           ;; For a temp file, save, and do make a non-numeric backup
  282.           ;; (unless make-backup-files is nil).
  283.           (let ((version-control nil)
  284.             (buffer-backed-up nil))
  285.         (save-buffer))
  286.         (if (and (buffer-modified-p)
  287.              (y-or-n-p (concat "Save file " buffer-file-name "? ")))
  288.         (save-buffer buffer)))
  289.       (server-buffer-done buffer)))))
  290.  
  291. ;; If a server buffer is killed, release its client.
  292. ;; I'm not sure this is really a good idea--do you want the client
  293. ;; to proceed using whatever is on disk in that file?
  294. (defun server-kill-buffer-query-function ()
  295.   (or (not server-buffer-clients)
  296.       (yes-or-no-p (format "Buffer `%s' still has clients; kill it? "
  297.                (buffer-name (current-buffer))))))
  298.  
  299. (add-hook 'kill-buffer-query-functions
  300.        'server-kill-buffer-query-function)
  301.  
  302. (defun server-kill-emacs-query-function ()
  303.   (let (live-client
  304.     (tail server-clients))
  305.     ;; See if any clients have any buffers that are still alive.
  306.     (while tail
  307.       (if (memq t (mapcar 'stringp (mapcar 'buffer-name (cdr (car tail)))))
  308.       (setq live-client t))
  309.       (setq tail (cdr tail)))
  310.     (or (not live-client)
  311.     (yes-or-no-p "Server buffers still have clients; exit anyway? "))))
  312.  
  313. (add-hook 'kill-emacs-query-functions 'server-kill-emacs-query-function)
  314.  
  315. (defun server-edit (&optional arg)
  316.   "Switch to next server editing buffer; say \"Done\" for current buffer.
  317. If a server buffer is current, it is marked \"done\" and optionally saved.
  318. When all of a client's buffers are marked as \"done\", the client is notified.
  319.  
  320. Temporary files such as MH <draft> files are always saved and backed up,
  321. no questions asked.  (The variable `make-backup-files', if nil, still
  322. inhibits a backup; you can set it locally in a particular buffer to
  323. prevent a backup for it.)  The variable `server-temp-file-regexp' controls
  324. which filenames are considered temporary.
  325.  
  326. If invoked with a prefix argument, or if there is no server process running, 
  327. starts server process and that is all.  Invoked by \\[server-edit]."
  328.  
  329.   (interactive "P")
  330.   (if (or arg
  331.       (not server-process)
  332.       (memq (process-status server-process) '(signal exit)))
  333.       (server-start nil)
  334.     (server-switch-buffer (server-done))))
  335.  
  336. (defun server-switch-buffer (next-buffer)
  337.   "Switch to another buffer, preferably one that has a client.
  338. Arg NEXT-BUFFER is a suggestion; if it is a live buffer, use it."
  339.   (cond ((windowp server-window)
  340.      (select-window server-window))
  341.     ((framep server-window)
  342.      (select-window (frame-selected-window server-window))))
  343.   (if (window-minibuffer-p (selected-window))
  344.       (select-window (next-window nil 'nomini t)))
  345.   (if next-buffer
  346.       (if (and (bufferp next-buffer)
  347.            (buffer-name next-buffer))
  348.       (switch-to-buffer next-buffer)
  349.     ;; If NEXT-BUFFER is a dead buffer,
  350.     ;; remove the server records for it
  351.     ;; and try the next surviving server buffer.
  352.     (server-switch-buffer
  353.      (server-buffer-done next-buffer)))
  354.     (if server-clients
  355.     (server-switch-buffer (nth 1 (car server-clients)))
  356.       (switch-to-buffer (other-buffer)))))
  357.  
  358. (global-set-key "\C-x#" 'server-edit)
  359.  
  360. (provide 'server)
  361.  
  362. ;;; server.el ends here
  363.